clear
capture log close
set more off
set mem 100m
set matsize 800
*#delimit ;
/*CHANGE THIS LINE TO REFLECT LOCAL DIRECTORY STRUCTURE*/
global REPDIR ="/Users/vojtabartos/Documents/4 Teaching/2018 Development Economics LMU/Tutorials/Exercise 2/Replication exercise 2 - Miguel and Roland (2011)/Bombing Vietnam Data Replication/"
cd "$REPDIR"
*log using vietbomb_log, t replace;

use MR2011_replication, clear


* Quang Tri district in Quang Tri province (an outlier in terms of ordnance used) already dropped from the dataset; no need to do anything
gen genpurposekm2=General_Purpose/area_tot_km2

* Replicate Table 1
* 1a
gen ordnance=General_Purpose+Cluster_Bomb+Missile+Rocket+Cannon_Artillery
gen ordnancekm2=(General_Purpose+Cluster_Bomb+Missile+Rocket+Cannon_Artillery)/area_tot_km2
gen ordnancekm2_2=ordnancekm2^2
xtile ordnancekm2_highestdecile=ordnancekm2, nquantiles(10)
recode ordnancekm2_highestdecile (1=0) (2=0) (3=0) (4=0) (5=0) (6=0) (7=0) (8=0) (9=0) (10=1)

******
* Table 1
sum ordnancekm2 ordnance General_Purpose Cluster_Bomb Missile Rocket Cannon_Artillery Incendiary WP Ammunition

foreach var of varlist Cluster_Bomb Missile Rocket Cannon_Artillery Incendiary WP Ammunition {
	pwcorr General_Purpose `var' [aw=pop_tot], sig
	}
******

* 1b
sort ordnancekm2
browse provincename districtname ordnancekm2

egen totordnance=sum(ordnance), by(provincename)
egen totareakm2=sum(area_tot_km2), by(provincename)
gen totordnancekm2=totordnance/totareakm2
sum totordnancekm2 if provincename=="Ha Noi (City)"
sum totordnancekm2 if provincename=="Ho Chi Minh (City)"
sum totordnancekm2 if provincename=="Quang Tri"
gen north=north_lat>17
replace north=0 if north_lat<17
egen northsouthordnance=sum(ordnance), by(north)
egen northsouthareakm2=sum(area_tot_km2), by(north)
gen northsouthordnancekm2=northsouthordnance/northsouthareakm2
sum northsouthordnancekm2 if north
sum northsouthordnancekm2 if !north

* 1c
*twoway (scatter ordnancekm2 north_lat) (lfit ordnancekm2 north_lat)
twoway scatter ordnancekm2 north_lat

* 1d
gen allordnance=Ammunition+Cannon_Artillery+Chemical+Cluster_Bomb+Flare+Fuel_Air_Explosive+General_Purpose+Grenade+Incendiary+Mine+Missile+Other+Rocket+Submunition+Torpedo+Unknown+UnlabeledUSAF+A+AAC+AC+ACC+AP+COM+COMM+CVT+HC+HCC+HCP+HCPD+HCVT+HE+HECVT+HEPD+HP+HVTF+ILL+ILLUM+ILUM+MK+MK07+MK10+MK12+MK7+MK70+MK8+P+P0+RAGON+RAP+SHRKE+UNLABELEDUSN+VC+VT+VTN+VTNSD+VTSD+W+WP
gen allordnancekm2=(Ammunition+Cannon_Artillery+Chemical+Cluster_Bomb+Flare+Fuel_Air_Explosive+General_Purpose+Grenade+Incendiary+Mine+Missile+Other+Rocket+Submunition+Torpedo+Unknown+UnlabeledUSAF+A+AAC+AC+ACC+AP+COM+COMM+CVT+HC+HCC+HCP+HCPD+HCVT+HE+HECVT+HEPD+HP+HVTF+ILL+ILLUM+ILUM+MK+MK07+MK10+MK12+MK7+MK70+MK8+P+P0+RAGON+RAP+SHRKE+UNLABELEDUSN+VC+VT+VTN+VTNSD+VTSD+W+WP)/area_tot_km2
* 1d.i
sum ordnance allordnance ordnancekm2 allordnancekm2
* 1d.ii
pwcorr ordnancekm2 allordnancekm2 [aw=pop_tot], sig

* 2
* 3
/* no control regressions for:
	Table 4 (poverty)
	Table 7 (electricity in panel A, literacy in panel B)
	Table 8 population density
	and split by south/north, urban/rural, adding nonlinearity + using dummy as in Table 5 (just without controls)
		- similarly also for the remaining explanatory variables
*/

global opt="replace"
foreach var of varlist poverty_p0 popdensity1999 elec_rate lit_rate {
	reg `var' ordnancekm2, robust
	outreg2 using "replication.xls" , $opt dec(5) se label addnote(Aggregate)
	global opt="append"
	reg `var' ordnancekm2 if south, robust
	outreg2 using "replication.xls" , $opt dec(5) se label addnote(South)
	reg `var' ordnancekm2 if !south, robust
	outreg2 using "replication.xls" , $opt dec(5) se label addnote(North)
	reg `var' ordnancekm2 if popdensity6061<200, robust
	outreg2 using "replication.xls" , $opt dec(5) se label addnote(Rural)
	reg `var' ordnancekm2 if popdensity6061>=200, robust
	outreg2 using "replication.xls" , $opt dec(5) se label addnote(Urban)
	reg `var' ordnancekm2 ordnancekm2_2, robust
	outreg2 using "replication.xls" , $opt dec(5) se label addnote(Aggregate)
	reg `var' ordnancekm2_highestdecile, robust
	outreg2 using "replication.xls" , $opt dec(5) se label addnote(Ordnance dummy)
	}
* 3e
* selection issues - bombing endogenous; we can try to control for potential factors influencing the choice of areas for bombing
* "The central estimation concern is the non-random geographic placement of U.S. bombing, in response to military strategy and needs, and most worryingly, potentially in response to local economic conditions."

* 5 
* see section 3.3

* 6
/* Create groups of global variables */
global x_elev = "area_251 area_501 area_over_1000m"
global x_gis = "north_lat"
global x_weather = "pre_avg tmp_avg"
global x_slope = "slp_c2 slp_c3 slp_c45"
global x_soil = "soil_1 soil_3 soil_6 soil_7 soil_8 soil_9 soil_10 soil_11 soil_12 soil_14 soil_24 soil_26 soil_33 soil_34 soil_35 soil_39 soil_40 soil_41"

replace popdensity6061=popdensity6061/100
	
/*
Replicating Table 4, including controls
*/
reg poverty_p0 ordnancekm2 popdensity6061 south $x_elev $x_weather $x_gis $x_soil
outreg2 using "replication.xls" , $opt dec(5) se label addnote(Aggregate)
* 6a
* correcting standard errors: heteroskedasticity robust standard errors clustered at the province level 
reg poverty_p0 ordnancekm2 popdensity6061 south $x_elev $x_weather $x_gis $x_soil, r cluster(province)
outreg2
* 6b
* including province fixed effects
* population density and south dummy perfectly collinear with province fixed effects
tab provincename, gen(provinceid)
reg poverty_p0 ordnancekm2 $x_elev $x_weather $x_gis $x_soil provinceid*, r cluster(province)
* this is just another way of doing the same as above
xi: reg poverty_p0 ordnancekm2 $x_elev $x_weather $x_gis $x_soil i.provincename, r cluster(province)
outreg2
* 7
/* problem is potential strategic nature of bombing - ordnance endogenous, we need an 
 exogenous source of variation */

* 8
* 8a
/* standard assumptions of instruments: instrument correlated with the instrumented 
variable, not correlated with the error term in the main specification */
/* "To address these concerns we develop an instrumental variable approach that relies
 on the arbitrary placement of the North Vietnam–South Vietnam border at the 17th
 parallel north latitude, as a result of Cold War negotiations between U.S. and
 Soviet officials." */
/* "A remaining econometric concern is whether the instrumental variable violates
 the exclusion restriction, in the sense that distance from the 17th parallel has
 an independent impact on postwar outcomes beyond any effects working through
 bombing intensity (conditional on the control variables). One possible concern
 is that the IV is correlated with distance to one of Vietnam's two major cities,
 Hanoi and Ho Chi Minh City. If remoteness from these two booming metropolitan
 areas is associated with lower incomes during the postwar period, as seems likely,
 this would generate a negative correlation between distance to the 17th parallel
 and poverty in 1999. However, despite any such possible bias, below we find no
 significant relationship between bombing and later poverty in the IV specification.
 In other words, despite the fact that districts near the 17th parallel had the
 double misfortune of being both heavily bombed and far from major national markets,
 they are currently no poorer than other regions (conditional on baseline characteristics)." */
* 8b.i
gen abs_dist_17=abs(17-north_lat)
* 8b.ii
* first stage regression
reg ordnancekm2 abs_dist_17 popdensity6061 south $x_elev $x_weather $x_gis $x_soil, r cluster(province)
* 8b.iii
* instrumending for ordnancekm2 using abs_dist_17
ivreg poverty_p0 (ordnancekm2=abs_dist_17) popdensity6061 south $x_elev $x_weather $x_gis $x_soil, r cluster(provincename) first
outreg2